6.4.4.2 Floating constants

Previous Table of Contents "New C Standard" commentary

floating-constant:
                decimal-floating-constant
                hexadecimal-floating-constant

decimal-floating-constant:
                fractional-constant exponent-part_opt floating-suffix_opt
                digit-sequence exponent-part floating-suffix_opt

hexadecimal-floating-constant:
                hexadecimal-prefix hexadecimal-fractional-constant
                                binary-exponent-part floating-suffix_opt
                hexadecimal-prefix hexadecimal-digit-sequence
                                binary-exponent-part floating-suffix_opt

fractional-constant:
                digit-sequence_opt . digit-sequence
                digit-sequence .

exponent-part:
                e sign_opt digit-sequence
                E sign_opt digit-sequence

sign: one of
                +  -

digit-sequence:
                digit
                digit-sequence digit

hexadecimal-fractional-constant:
                hexadecimal-digit-sequence_opt .
                                hexadecimal-digit-sequence
                hexadecimal-digit-sequence .

binary-exponent-part:
                p sign_opt digit-sequence
                P sign_opt digit-sequence

hexadecimal-digit-sequence:
                hexadecimal-digit
                hexadecimal-digit-sequence hexadecimal-digit

floating-suffix: one of
                f  l  F  L

843 A floating constant has a significand part that may be followed by an exponent part and a suffix that specifies its type.

844 The components of the significand part may include a digit sequence representing the whole-number part, followed by a period (.), followed by a digit sequence representing the fraction part.

845 The components of the exponent part are an e, E, p, or P followed by an exponent consisting of an optionally signed digit sequence.

846 Either the whole-number part or the fraction part has to be present;

847 for decimal floating constants, either the period or the exponent part has to be present.

848 The significand part is interpreted as a (decimal or hexadecimal) rational number;

849 the digit sequence in the exponent part is interpreted as a decimal integer.

850 For decimal floating constants, the exponent indicates the power of 10 by which the significand part is to be scaled.

851 For hexadecimal floating constants, the exponent indicates the power of 2 by which the significand part is to be scaled.

852 For decimal floating constants, and also for hexadecimal floating constants when FLT_RADIX is not a power of 2, the result is either the nearest representable value, or the larger or smaller representable value immediately adjacent to the nearest representable value, chosen in an implementation-defined manner.

853 For hexadecimal floating constants when FLT_RADIX is a power of 2, the result is correctly rounded.

854 An unsuffixed floating constant has type double.

855 If suffixed by the letter f or F, it has type float.

856 If suffixed by the letter l or L, it has type long double.

857 Floating constants are converted to internal format as if at translation-time.

858 The conversion of a floating constant shall not raise an exceptional condition or a floating-point exception at execution time.

859 The implementation should produce a diagnostic message if a hexadecimal constant cannot be represented exactly in its evaluation format;

860 the implementation should then proceed with the translation of the program.

861 The translation-time conversion of floating constants should match the execution-time conversion of character strings by library functions, such as strtod, given matching inputs suitable for both conversions, the same result format, and default execution-time rounding.⁶⁴⁾

862 64) The specification for the library functions recommends more accurate conversion than required for floating constants (see 7.20.1.3).